home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / programm.ing / falcon / a56v12st.lzh / a56 / examples / x.a56 < prev    next >
Encoding:
Text File  |  1994-09-02  |  10.2 KB  |  589 lines
  1. ;***************************************************************
  2. ; 
  3. ; A stereo reverb for the DSP56001 signal processor.  Based on,
  4. ; 
  5. ;    Moorer, James A. "About This Reverberation Business."
  6. ;    Computer Music Journal Vol 3, No. 2 (1979), pp. 13-28.
  7. ;
  8. ;   reprinted in,
  9. ;
  10. ;    Roads, Curtis, and Strawn, John, ed., _Foundations
  11. ;    of Computer Music_, pp. 605-639, MIT Press, 1985.
  12. ;    ISBN 0-262-68051-3 (paper)
  13. ;    ISBN 0-262-181142 (hard)
  14. ;
  15. ; Each comb filter uses a low-pass filter in the feedback path.
  16. ; The combs and all-pass filter delay lines use a prime-number
  17. ; of stages to improve diffusion.
  18. ;
  19. ; The output all-pass stage is replicated for left/right
  20. ; decorrelation.  Each side uses slightly different gains
  21. ; and delay lengths.  This works a lot better than just inverting
  22. ; one side and adding in the input.
  23. ;
  24. ; I left out the early-reflection FIR filter because I needed the cycles
  25. ; for other effects.
  26. ;
  27. ; Quinn Jensen (jensenq@qcj.icon.com)
  28. ;
  29. ;***************************************************************
  30.     psect    vectors        p:$0000:$0040
  31.     psect    hf_code        p:$0040:$0200
  32.     psect    hf_datax    x:$0000:$0040
  33.     psect    hf_datax1    x:$0040:$0100
  34.     psect    hf_datay    y:$0000:$0040
  35.     psect    hf_datay1    y:$0040:$0100
  36.     psect    midi_data    x:$0400:$1000
  37.     psect    lo_data        x:$1000:$F000
  38.     psect    lo_code        p:$F000:$FE00
  39.     psect    loader        p:$FE00:$FFFF
  40.     psect    iox        x:$FFC0:$FFFF
  41.     psect    ioy        y:$FFC0:$FFFF
  42. ;
  43. ; some oft-used constants
  44. ;
  45.     psect    hf_datax
  46. ffff    dc    $FFFF        ;used a lot for modulus
  47. ONE    equ    $7FFFFF        ;"one"
  48. one    dc    ONE        ;"one"
  49. ;
  50. ; L/R inputs and outputs
  51. ;
  52. in_l    dc    0.0      
  53. in_r    dc    0.0      
  54. out_l    dc    0.0      
  55. out_r    dc    0.0      
  56. ;
  57. ; recompute comb gains g1 and g2
  58. ;
  59. recalc_comb_gains
  60.     move        x:<constsp,r0
  61.     movec        x:<ffff,m0
  62.     move        x:lowpass_cutoff_start,b
  63.     move        x:lowpass_cutoff_slope,y1
  64.     move        x:comb_g,x1
  65.     move        #0.5,x0
  66.  
  67.     do    #6,recalc_loop
  68.       clr    a    (r0)+        ;skip over the modulus const
  69.       add    x0,a    b,y0
  70.       mac    x0,y0,a            ;g1 = .5 * b + .5
  71.       clr    a    a,y0        ;y0 = g1
  72.       add    x1,a    y0,y:(r0)+    ;store g1 in table
  73.       macr    -x1,y0,a        ;g2 = g(1-g1) = g - g*g1 with limiting
  74.       add    y1,b    a,y:(r0)+    ;update b, store g2 in table
  75. recalc_loop
  76.     rts
  77.  
  78.     psect    midi_data
  79. ;
  80. ; default values for midi-derived parameters
  81. ;
  82. lowpass_cutoff_start
  83.     dc    -0.3906250    ; ctl value of 39
  84. lowpass_cutoff_slope
  85.     dc    0.0468750    ; ctl value of 67
  86. comb_g
  87.     dc    0.8325507974    ; ctl value of 57
  88. ;
  89. ; preset comb-length arrays
  90. ;
  91.  
  92.  
  93.  
  94. ; comb lenths 383,433,467,523,557,601
  95. comblen_1
  96.     dc    383-1
  97.     dc    433-1
  98.     dc    467-1
  99.     dc    523-1
  100.     dc    557-1
  101.     dc    601-1
  102.  
  103.  
  104. ; comb lenths 509,577,631,701,743,797
  105. comblen_2
  106.     dc    509-1
  107.     dc    577-1
  108.     dc    631-1
  109.     dc    701-1
  110.     dc    743-1
  111.     dc    797-1
  112.  
  113.  
  114. ; comb lenths 683,769,839,937,991,1069
  115. comblen_3
  116.     dc    683-1
  117.     dc    769-1
  118.     dc    839-1
  119.     dc    937-1
  120.     dc    991-1
  121.     dc    1069-1
  122.  
  123.  
  124. ; comb lenths 919,1021,1117,1249,1319,1427
  125. comblen_4
  126.     dc    919-1
  127.     dc    1021-1
  128.     dc    1117-1
  129.     dc    1249-1
  130.     dc    1319-1
  131.     dc    1427-1
  132.  
  133.  
  134. ; comb lenths 1223,1367,1489,1657,1759,1901
  135. comblen_5
  136.     dc    1223-1
  137.     dc    1367-1
  138.     dc    1489-1
  139.     dc    1657-1
  140.     dc    1759-1
  141.     dc    1901-1
  142.  
  143.  
  144. ; comb lenths 1627,1823,1987,2213,2341,2539
  145. comblen_6
  146.     dc    1627-1
  147.     dc    1823-1
  148.     dc    1987-1
  149.     dc    2213-1
  150.     dc    2341-1
  151.     dc    2539-1
  152.  
  153.  
  154. ;;;;;;;;;;;;;;;;;;;;;;;
  155. ; reverb filters
  156. ;;;;;;;;;;;;;;;;;;;;;;;
  157.  
  158. ;  Reverb filter lengths and coefficients     
  159. ;  6 comb reverb with prime delay lines
  160. ;  Sun Oct 24 13:53:51 1993
  161. ;  
  162. ;                          Sample rate        32.5520830 kHz      
  163. ;                          g                   0.8400000
  164. ;  
  165. ;                    status      STABLE       
  166. ;         delay      near prime lengths actual
  167. ;  stage   (ms)   1  high   low  best  delay        g1        g2
  168. ;  ---------------------------------------------------------------
  169. ;  Comb 1  50.0  1628  1637  1627  1627 49.981 0.3064583 0.5825750
  170. ;  Comb 2  56.0  1823  1823  1823  1823 56.003 0.3264583 0.5657750
  171. ;  Comb 3  61.0  1986  1987  1979  1987 61.041 0.3464583 0.5489750
  172. ;  Comb 4  68.0  2214  2221  2213  2213 67.983 0.3594792 0.5380375
  173. ;  Comb 5  72.0  2344  2347  2341  2341 71.916 0.3694792 0.5296375
  174. ;  Comb 6  78.0  2539  2539  2539  2539 77.998 0.4243750 0.4835250
  175. ;  All      6.0   195   197   193   193  5.929 0.7000000
  176.  
  177. ; COMB(name, length, modulus, g1, g2)
  178.  
  179.  
  180.  
  181.  
  182. ; storage for "c1" length=1627 modulus=2048 g1=0.3046875 g2=0.5812382
  183.  
  184.     psect    lo_data
  185.     align    2048
  186. c1d
  187. c1m    equ    1627-1
  188.     org    x:c1d+c1m
  189.     psect    hf_datax
  190. c1g1    equ    0.3046875
  191. c1g2    equ    0.5812382
  192.  
  193.  
  194. ; storage for "a1" length=193 modulus=256 g1=0.7000000 g2=0.0000000
  195.  
  196.     psect    lo_data
  197.     align    256
  198. a1d
  199. a1m    equ    193-1
  200.     org    x:a1d+a1m
  201.     psect    hf_datax
  202. a1g1    equ    0.7000000
  203. a1g2    equ    0.0000000
  204.  
  205.  
  206. ; storage for "c2" length=1823 modulus=2048 g1=0.3281250 g2=0.5616459
  207.  
  208.     psect    lo_data
  209.     align    2048
  210. c2d
  211. c2m    equ    1823-1
  212.     org    x:c2d+c2m
  213.     psect    hf_datax
  214. c2g1    equ    0.3281250
  215. c2g2    equ    0.5616459
  216.  
  217.  
  218. ; storage for "c3" length=1987 modulus=2048 g1=0.3515625 g2=0.5420536
  219.  
  220.     psect    lo_data
  221.     align    2048
  222. c3d
  223. c3m    equ    1987-1
  224.     org    x:c3d+c3m
  225.     psect    hf_datax
  226. c3g1    equ    0.3515625
  227. c3g2    equ    0.5420536
  228.  
  229.  
  230. ; storage for "c4" length=2213 modulus=4096 g1=0.3750000 g2=0.5224613
  231.  
  232.     psect    lo_data
  233.     align    4096
  234. c4d
  235. c4m    equ    2213-1
  236.     org    x:c4d+c4m
  237.     psect    hf_datax
  238. c4g1    equ    0.3750000
  239. c4g2    equ    0.5224613
  240.  
  241.  
  242. ; storage for "a2" length=207 modulus=256 g1=0.7500000 g2=0.0000000
  243.  
  244.     psect    lo_data
  245.     align    256
  246. a2d
  247. a2m    equ    207-1
  248.     org    x:a2d+a2m
  249.     psect    hf_datax
  250. a2g1    equ    0.7500000
  251. a2g2    equ    0.0000000
  252.  
  253.  
  254. ; storage for "c5" length=2341 modulus=4096 g1=0.3984375 g2=0.5028690
  255.  
  256.     psect    lo_data
  257.     align    4096
  258. c5d
  259. c5m    equ    2341-1
  260.     org    x:c5d+c5m
  261.     psect    hf_datax
  262. c5g1    equ    0.3984375
  263. c5g2    equ    0.5028690
  264.  
  265.  
  266. ; storage for "c6" length=2539 modulus=4096 g1=0.4218750 g2=0.4832767
  267.  
  268.     psect    lo_data
  269.     align    4096
  270. c6d
  271. c6m    equ    2539-1
  272.     org    x:c6d+c6m
  273.     psect    hf_datax
  274. c6g1    equ    0.4218750
  275. c6g2    equ    0.4832767
  276.  
  277.  
  278.     psect    hf_datax
  279. a1r    dc    a1d
  280. a1md    dc    a1m
  281. a1g1d    dc    a1g1
  282. a2r    dc    a2d
  283. a2md    dc    a2m
  284. a2g1d    dc    a2g1
  285.     psect    hf_datay
  286. curaddrp
  287.     dc    curaddr
  288.     psect    hf_datax
  289. constsp    dc    consts
  290. lowstatep
  291.     dc    lowstate
  292.  
  293.     psect    hf_datax1
  294. curaddr
  295.     dc    c1d
  296.     dc    c2d
  297.     dc    c3d
  298.     dc    c4d
  299.     dc    c5d
  300.     dc    c6d
  301.  
  302.     psect    hf_datay1
  303. consts
  304.     dc    c1m
  305.     dc    c1g1
  306.     dc    c1g2
  307.     dc    c2m
  308.     dc    c2g1
  309.     dc    c2g2
  310.     dc    c3m
  311.     dc    c3g1
  312.     dc    c3g2
  313.     dc    c4m
  314.     dc    c4g1
  315.     dc    c4g2
  316.     dc    c5m
  317.     dc    c5g1
  318.     dc    c5g2
  319.     dc    c6m
  320.     dc    c6g1
  321.     dc    c6g2
  322.  
  323.     psect    hf_datax1
  324. lowstate
  325.     dc    0
  326.     dc    0
  327.     dc    0
  328.     dc    0
  329.     dc    0
  330.     dc    0
  331.  
  332. ;;;;;;;;;;;;;;;;;;;;;;;
  333. ; miscellaneous signals
  334. ;;;;;;;;;;;;;;;;;;;;;;;
  335.  
  336.     psect    hf_datax
  337. L_overall
  338.     dc    $7FFFFF
  339. R_overall
  340.     dc    $7FFFFF
  341.  
  342. ;;;;;;;;;;;;;;;;;;;;;;;
  343. ; signal vector
  344. ;;;;;;;;;;;;;;;;;;;;;;;
  345.     psect    hf_datax
  346.     align 8
  347. signal_vector
  348. Lin    dc    0.0
  349. Rin    dc    0.0
  350. Reverb_L
  351.     dc    0.0
  352. Reverb_R    
  353.     dc    0.0
  354.  
  355. Lout
  356.     dc    0
  357. Rout
  358.     dc    0
  359.  
  360.     psect hf_datay
  361. signal_vectorp
  362.     dc    signal_vector
  363. signal_mod
  364.     dc    4-1
  365.  
  366. gain_vectorsp
  367.     dc    gain_vectors
  368. ;;;;;;;;;;;;;;;;;;;;;;;
  369. ; gain matrix
  370. ;;;;;;;;;;;;;;;;;;;;;;;
  371.     psect    hf_datay1
  372. gain_vectors
  373. Reverb_gain_vector
  374. Reverb_Lin    dc 0.5
  375. Reverb_Rin    dc 0.5
  376. Reverb_Reverb_L    dc 0.0
  377. Reverb_Reverb_R    dc 0.0
  378.  
  379. Lout_gain_vector
  380. Lout_Lin    dc 0.0
  381. Lout_Rin    dc 0.0
  382. Lout_Reverb_L    dc ONE
  383. Lout_Reverb_R    dc 0.0
  384.  
  385. Rout_gain_vector
  386. Rout_Lin    dc 0.0
  387. Rout_Rin    dc 0.0
  388. Rout_Reverb_L    dc 0.0
  389. Rout_Reverb_R    dc -1.0
  390.  
  391. ;***************************************************************
  392. ;
  393. ;    init code - call hf_init at first and any time when
  394. ;    parameters change
  395. ;
  396. ;***************************************************************
  397.     psect    lo_code
  398.  
  399. hf_init
  400. ;
  401. ;    clear out the filter delay lines
  402. ;
  403.  
  404.  
  405.  
  406.     move        #c1d,r0
  407.     movec        #c1m,m0
  408.     jsr    clear_line_r0
  409.  
  410.  
  411.     move        #c2d,r0
  412.     movec        #c2m,m0
  413.     jsr    clear_line_r0
  414.  
  415.  
  416.     move        #c3d,r0
  417.     movec        #c3m,m0
  418.     jsr    clear_line_r0
  419.  
  420.  
  421.     move        #c4d,r0
  422.     movec        #c4m,m0
  423.     jsr    clear_line_r0
  424.  
  425.  
  426.     move        #c5d,r0
  427.     movec        #c5m,m0
  428.     jsr    clear_line_r0
  429.  
  430.  
  431.     move        #c6d,r0
  432.     movec        #c6m,m0
  433.     jsr    clear_line_r0
  434.  
  435.  
  436.     move        #a1d,r0
  437.     movec        #a1m,m0
  438.     jsr    clear_line_r0
  439.  
  440.  
  441.     move        #a2d,r0
  442.     movec        #a2m,m0
  443.     jsr    clear_line_r0
  444.  
  445.     jsr    recalc_comb_gains
  446.     rts
  447.  
  448. clear_line_r0
  449.     clr    a
  450.     rep    #0
  451.       move        a,x:(r0)+
  452.     rts
  453.  
  454. ;***************************************************************
  455. ;
  456. ;    sample rate computations
  457. ;
  458. ;    Call hf_comp once per sample.
  459. ;    Globals in_l and in_r should have the left and right
  460. ;    input samples.  When hf_comp returns, out_l and out_r
  461. ;    will be ready.
  462. ;
  463. ;***************************************************************
  464.  
  465. ;
  466. ; fs = 32.552083 kHz
  467. ;
  468.     psect    hf_code
  469.  
  470. hf_comp
  471. ;
  472. ;    copy inputs
  473. ;
  474.     move        x:<in_l,a
  475.     move        a,x:<Lin
  476.     move        x:<in_r,a
  477.     move        a,x:<Rin
  478. ;
  479. ;    compute outputs using matrix multiply
  480. ;
  481. ; [reverb_in out_l out_r] = [gain_vector] * [signal_vector]
  482. ;
  483.     move        y:<signal_vectorp,r0
  484.     movec        y:<signal_mod,m0
  485.     move        y:<gain_vectorsp,r4
  486.     movec        x:<ffff,m4
  487.     move        x:<L_overall,y1        ;and wait for m4
  488.     clr    a    x:(r0)+,x0 y:(r4)+,y0
  489.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  490.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  491.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  492.     macr    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  493.     clr    a    a,b            ;b is reverb_in
  494.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  495.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  496.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  497.     macr    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  498.     clr    a    a,x1
  499.     mpy    x1,y1,a    x:<R_overall,y1
  500.     clr    a    a,x:<out_l
  501.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  502.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  503.     mac    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  504.     macr    x0,y0,a    x:(r0)+,x0 y:(r4)+,y0
  505.     clr    a    a,x1
  506.     mpy    x1,y1,a
  507.     clr    a    a,x:<out_r
  508. ;
  509. ; r1    lowstate vector
  510. ; m1    -1
  511. ; r4    ptr to modulus,g1,g2 constants
  512. ; m4    -1
  513. ; r5    curaddr ptr
  514. ; m5    -1
  515. ; b    comb out accum
  516. ; x0    scaled comb in
  517. ;
  518. ;
  519. ;    set up reverb input
  520. ;
  521.     clr    b    b,x0            ;get reverb_in
  522.     move        #1.0/16,x1        ;allow 4 bits of headroom
  523.     mpyr    x0,x1,a                ;and 4 bits of noise
  524.     move        a,x0
  525.     move        x:<lowstatep,r1
  526.     movec        x:<ffff,m1
  527.     move        x:<constsp,r4
  528.     movec        m1,m4
  529.     move            y:<curaddrp,r5
  530.     movec        m1,m5
  531. ;
  532. ;    do the six combs
  533. ;
  534.     do    #6,comb_loop
  535.       move        x:(r5),r0        ;r0=curaddr
  536.       movec        y:(r4)+,m0        ;m0=modulus
  537.       move        x:(r1),x1 y:(r4)+,y1    ;x1=lowstate, y1=g1, wait for m0
  538.       move        x:(r0)+,y0        ;y0=delay out
  539.       add    y0,b        y0,a        ;a=delay out
  540.       macr    x1,y1,a        y:(r4)+,y1    ;a=out+g1*lowstate, y1=g2
  541.       clr    a          a,x:(r1)+ a,y0        ;y0=new lowstate
  542.       add    x0,a    r0,x:(r5)+        ;a=in, save ptr
  543.       macr    y0,y1,a                ;a=in+g2*g1*lowstate
  544.       move        a,x:-(r0)        ;store delay in (takes 2 cyc)
  545. comb_loop
  546. ;
  547. ;    scale
  548. ;
  549.     rnd    b    #$15,x0        ;scale by ~1/6
  550.     move        b,y0
  551.     mpyr    x0,y0,b
  552.     move        b,y1        ;save b for right chan
  553. ;
  554. ;    allpass L
  555. ;
  556.     move        x:<a1r,r0
  557.     movec        x:<a1md,m0
  558.     move        x:<a1g1d,x0
  559.     move        x:(r0),x1
  560.     macr    x0,x1,b    x1,a
  561.     move            b,y0
  562.     macr    -x0,y0,a b,x:(r0)+
  563.     asl    a          r0,x:<a1r
  564.     asl    a            ;get rid of the headroom
  565.     asl    a
  566.     asl    a
  567.     move        a,x:<Reverb_L
  568. ;
  569. ;    allpass R
  570. ;
  571.     tfr    y1,b    x:<a2r,r0
  572.     movec        x:<a2md,m0
  573.     neg    b    x:<a2g1d,x0
  574.     move        x:(r0),x1
  575.     macr    x0,x1,b    x1,a
  576.     move            b,y0
  577.     macr    -x0,y0,a b,x:(r0)+
  578.     asl    a    r0,x:<a2r
  579.     asl    a
  580.     asl    a
  581.     asl    a
  582.     move        a,x:<Reverb_R
  583. ;
  584. ;    done
  585. ;
  586.     rts
  587.  
  588.     end
  589.